Add Elixir ESP NVS example

Author: mnishiguchi

elixir/EspNvs/README.md

@@ -0,0 +1,17 @@
+<!---
+  Copyright 2023 Fred Dushin <fred@dushin.net>
+  Copyright 2026 Masatoshi Nishiguchi
+
+  SPDX-License-Identifier: Apache-2.0 OR LGPL-2.1-or-later
+-->
+
+# `EspNvs` Application
+
+Welcome to the `EspNvs` AtomVM application.
+
+The `EspNvs` AtomVM application uses ESP32 non-volatile storage (NVS) to record the number of times the device has restarted.
+If the NVS storage has not been set for this application, it will be initialized with a count of 0. The device will then sleep for 10 seconds and restart. After each restart, the number of restarts is incremented and stored in NVS.
+
+For more information about programming on the AtomVM platform, see the [AtomVM Programmers Guide](https://doc.atomvm.org/latest/programmers-guide.html).
+
+For general information about building and executing Elixir AtomVM example programs, see the Elixir example program [README](../README.md).

elixir/EspNvs/lib/esp_nvs.ex

@@ -0,0 +1,88 @@
+#
+# This file is part of AtomVM.
+#
+# Copyright 2026 Masatoshi Nishiguchi
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+# SPDX-License-Identifier: Apache-2.0 OR LGPL-2.1-or-later
+#
+
+defmodule EspNvs do
+  @moduledoc """
+  Demonstrates ESP32 NVS usage by persisting a restart counter.
+  """
+
+  @compile {:no_warn_undefined, :atomvm}
+  @compile {:no_warn_undefined, :esp}
+
+  @nvs_namespace :esp_nvs
+  @nvs_key :starts
+  @restart_delay_ms :timer.seconds(10)
+
+  require Record
+  Record.defrecord(:state, count: 0)
+
+  def start do
+    case verify_platform(:atomvm.platform()) do
+      :ok ->
+        load_state() |> increment_state() |> save_state()
+
+        IO.puts("Restarting in 10 seconds ...")
+        :timer.sleep(@restart_delay_ms)
+        :esp.restart()
+
+      error ->
+        error
+    end
+  end
+
+  defp load_state do
+    IO.puts("Loading count from NVS ...")
+
+    case :esp.nvs_get_binary(@nvs_namespace, @nvs_key) do
+      :undefined ->
+        IO.puts("This device has not recorded the number of starts. Initializing to 0.")
+        state()
+
+      bin ->
+        case :erlang.binary_to_term(bin) do
+          state(count: count) ->
+            IO.puts("Loaded count: #{count}")
+            state(count: count)
+
+          _ ->
+            IO.puts("Error: bad value, resetting to 0.")
+            state()
+        end
+    end
+  end
+
+  defp save_state(state) do
+    IO.puts("Saving count to NVS ...")
+    :esp.nvs_set_binary(@nvs_namespace, @nvs_key, :erlang.term_to_binary(state))
+  end
+
+  defp increment_state(state(count: count)) when is_integer(count) do
+    IO.puts("This device has restarted #{count + 1} time(s).")
+    state(count: count + 1)
+  end
+
+  defp increment_state(_) do
+    IO.puts("Error: bad value, resetting to 0.")
+    state()
+  end
+
+  defp verify_platform(:esp32), do: :ok
+  defp verify_platform(platform), do: {:error, {:unsupported_platform, platform}}
+end

elixir/EspNvs/mix.exs

@@ -0,0 +1,51 @@
+#
+# This file is part of AtomVM.
+#
+# Copyright 2026 Masatoshi Nishiguchi
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+# SPDX-License-Identifier: Apache-2.0 OR LGPL-2.1-or-later
+#
+
+defmodule EspNvs.MixProject do
+  use Mix.Project
+
+  def project do
+    [
+      app: :esp_nvs,
+      version: "0.1.0",
+      elixir: "~> 1.17",
+      start_permanent: Mix.env() == :prod,
+      deps: deps(),
+      atomvm: [
+        start: EspNvs,
+        flash_offset: 0x250000
+      ]
+    ]
+  end
+
+  # Run "mix help compile.app" to learn about applications.
+  def application do
+    [
+      extra_applications: [:logger]
+    ]
+  end
+
+  # Run "mix help deps" to learn about dependencies.
+  defp deps do
+    [
+      {:exatomvm, git: "https://github.com/atomvm/ExAtomVM/", branch: "main"}
+    ]
+  end
+end

elixir/README.md

@@ -16,8 +16,9 @@ Some example programs can only run on specific platform.  The following table su
 |-----------------|-------|-------|------|--------|--------------|
 | Blinky          | ✅ | ✅ | ✅ | ✦ | ❌ |
 | HelloWorld      | ✅ | ✅ | ✅ | ✅ | ✅ |
-| LEDC_Example    | ✅ | ❌ | ❌ | ❌ | ❌ |
-| WifiExample     | ✅ | ❌ | ❌ | ✅ | ❌ |
+| LEDC            | ✅ | ❌ | ❌ | ❌ | ❌ |
+| Wifi            | ✅ | ❌ | ❌ | ✅ | ❌ |
+| EspNvs          | ✅ | ❌ | ❌ | ❌ | ❌ |
 
 ✦ Works, but requires editing to use onboard LED, see the README in the examples directory.