Weak RSA key size query, docs, test

Author: chanel-y

powershell/ql/lib/semmle/code/powershell/security/cryptography/CryptoArtifact.qll

@@ -36,3 +36,9 @@ abstract class BlockMode extends CryptographicAlgorithm {
     else result = unknownAlgorithm()
   }
 }
+
+abstract class AsymmetricKeyCreation extends CryptographicArtifact {
+  abstract string getAlgorithmName();
+
+  abstract int getKeySize();
+}

powershell/ql/lib/semmle/code/powershell/security/cryptography/CryptographyModule.qll

@@ -194,3 +194,45 @@ class CipherBlockModeEnum extends BlockMode {
 
   override string getName() { result = modeName }
 }
+
+class RsaCreateKeyCreation extends AsymmetricKeyCreation, DataFlow::CallNode {
+  int keySize;
+
+  RsaCreateKeyCreation() {
+    exists(string method |
+      method = ["create", "new"] and
+      this =
+        API::getTopLevelMember("system")
+            .getMember("security")
+            .getMember("cryptography")
+            .getMember(["rsa", "rsacryptoserviceprovider"])
+            .getMember(method)
+            .asCall()
+    ) and
+    keySize = this.getAnArgument().asExpr().getExpr().(ConstExpr).getValueString().toInt()
+  }
+
+  override string getAlgorithmName() { result = "rsa" }
+
+  override int getKeySize() { result = keySize }
+}
+
+class RsaCspObjectKeyCreation extends AsymmetricKeyCreation, CryptoAlgorithmObjectCreation {
+  int keySize;
+
+  RsaCspObjectKeyCreation() {
+    objectName =
+      [
+        "system.security.cryptography.rsacryptoserviceprovider",
+        "rsacryptoserviceprovider"
+      ] and
+    exists(DataFlow::Node arg |
+      arg = this.getAnArgument() and
+      keySize = arg.asExpr().getExpr().(ConstExpr).getValueString().toInt()
+    )
+  }
+
+  override string getAlgorithmName() { result = "rsa" }
+
+  override int getKeySize() { result = keySize }
+}

powershell/ql/src/queries/security/cwe-326/WeakAsymmetricKey.ql

@@ -0,0 +1,40 @@
+<!DOCTYPE qhelp PUBLIC "-//Semmle//qhelp//EN" "qhelp.dtd">
+<qhelp>
+  <overview>
+    <p>
+      Modern encryption relies on it being computationally infeasible to break the cipher and
+      decode a message without the key. As computational power increases, the ability to break
+      ciphers grows and keys need to become larger.
+    </p>
+    <p>
+      RSA keys smaller than 2048 bits are considered weak and can potentially be broken using
+      modern hardware. Using such keys compromises the confidentiality and integrity of
+      encrypted data.
+    </p>
+  </overview>
+
+  <recommendation>
+    <p>
+      Use an RSA key size of at least 2048 bits. For long-term security, consider using
+      4096-bit keys.
+    </p>
+    <p>
+      When calling <code>[System.Security.Cryptography.RSA]::Create()</code> or creating an
+      <code>RSACryptoServiceProvider</code>, always specify a key size of 2048 or greater.
+    </p>
+  </recommendation>
+
+  <example>
+    <p>
+      The following example shows the creation of an RSA key with only 1024 bits, which is
+      considered weak:
+    </p>
+    <sample src="test.ps1" />
+  </example>
+
+  <references>
+    <li>NIST, SP 800-131A: <a href="https://csrc.nist.gov/publications/detail/sp/800-131a/rev-2/final">Transitioning the Use of Cryptographic Algorithms and Key Lengths</a>.</li>
+    <li>Wikipedia: <a href="https://en.wikipedia.org/wiki/RSA_(cryptosystem)">RSA cryptosystem</a>.</li>
+    <li>CWE-327: <a href="https://cwe.mitre.org/data/definitions/327.html">Use of a Broken or Risky Cryptographic Algorithm</a>.</li>
+  </references>
+</qhelp>

powershell/ql/src/queries/security/cwe-327/WeakAsymmetricKeySize.qhelp

@@ -0,0 +1,22 @@
+/**
+ * @name Weak asymmetric key size
+ * @description Using RSA keys smaller than 2048 bits does not provide adequate security.
+ * @kind problem
+ * @problem.severity error
+ * @security-severity 7.5
+ * @precision high
+ * @id powershell/weak-asymmetric-key-size
+ * @tags security
+ *       external/cwe/cwe-327
+ */
+
+import powershell
+import semmle.code.powershell.dataflow.DataFlow
+import semmle.code.powershell.security.cryptography.Concepts
+
+from AsymmetricKeyCreation keyCreation, int keySize
+where
+  keySize = keyCreation.getKeySize() and
+  keySize < 2048
+select keyCreation,
+  "RSA key size " + keySize.toString() + " bits is below the minimum of 2048 bits."

powershell/ql/src/queries/security/cwe-327/WeakAsymmetricKeySize.ql

@@ -0,0 +1 @@
+queries/security/cwe-327/WeakAsymmetricKeySize.ql